data normvar;
	 keep x sample c scale m n;
	  scale=2; m=3; n=10; c=100; nsim=n*c; *n=sample size c=#samples;
	   do i=1 to nsim;
	      x=rannor(1)*scale+m;
		  sample=int((i-1)/n)+1; 	/* la funzione int(x) restituisce la parte intera di x */
	      output;
	   end;
	 run;
	 proc means data=normvar min max;
	 var x; run;
	proc univariate data=normvar mu0=3;
	var x;
	   histogram x / normal(percents=2.5 20 40 60 80 95 97.5 midpercents mu=3 sigma=2);*endpoints = 70 to 130 by 5;
	    *le opzioni di normal richiedono i percentili osservati e stimati 
	   con i parametri dati;
	   inset n='Sample size' std='Std Dev' (5.2) normal(ksdpval); 
	   *ksdpval: kolmogorov-smirnov edf test pvalue;
	    qqplot x  / normal(mu=3 sigma=2) square ctext=blue;
	run;

	 /* Calcolo della media campionaria */
	proc means data=normvar noprint;
	 var x scale m ;
	 by sample;
	   output out=cimean lclm=lx uclm=ux mean=meanx scale m n=size; 
	run; 
    /* Verifica della copertura nominale*/

	data coverage;
	 set cimean;
	 count=0;
	 if lx<m<ux then count=1;
	run;

	proc means data=coverage sum mean;
	 var count;
	run;

	 /* Verifiche sulla distribuzione della media campionaria */

	proc means data=cimean mean var std; *noprint;
	 var meanx scale m size;
	   output out=distr  mean=meanxmean scale m size std=stdxmean var=varmean; 
	run; 

	data true;
	 set distr;
	 vartrue=(scale**2)/size;
	 stdErrtrue=scale/sqrt(size);
	 keep vartrue varmean stdErrtrue stdxmean;
	run;

	proc print data=true;
	 var vartrue varmean stdErrtrue stdxmean;
	run;